***********************************************************************
***********           PANJIT International Inc.             ***********
***********************************************************************
*Jul 05, 2019                                                         *
*                                                                     *
*This SPICE Model describes the characteristics of a typical device   *
*and does not respresent the specification. Designer should refer to  *
*the same type name data sheet for specification limits.              *
***********************************************************************
*$
.subckt   PJQ5466A-AU   D   G   S
*****param & model definition***
.model  dmos  nmos(
+    l = 1e-6		  w = 1e-6			level = 3
+  vto = 2.25		 kp = 31.2)
.model  dds   d(
+   is = 3.579e-12	  n = 1.045			   rs = 1.051e-4			ikf = 1.247
+   eg = 1.000		trs1 = 1.000e-3)
.model  dbody d(
+   is = 3.579e-12	  n = 1.045			   rs = 1.051e-4			ikf = 1.247
+  cjo = 6.009e-10	  m = 6.320e-1		   vj = 7.839e-1
+   bv = 66			ibv = 250e-6		 tbv1 = 8.244e-4			tt = 25n)
.model  inter  nmos(
+  vto = 0			 kp = 10			level = 1)
.model  dgd    d(
+  cjo = 1.784-10		  m = 6.150e-1		   vj = 1.186)
.param
+  cgs = 2.174e-9		cgd = 1.827e-10
+   rd = 3e-3		 ra = 3e-3		trd = 4.572e-2
*****function & circuit***
rg	  G  1t   1
cgs	 1t   3   {cgs}   ic = 0
egv	  2t  3   table   {v(1t, S)} 
+((0   , 0   ),
+ (1   , 1   ), 
+ (2   , 2   ),
+ (2.5 , 2.5 ),
+ (3   , 3   ),
+ (3.25, 3.25),
+ (3.5 , 3.6 ),
+ (4   , 4.10),
+ (4.5 , 4.45),
+ (5   , 4.65),
+ (6   , 4.8 ),
+ (8   , 4.95),
+ (10  , 5.05),   
+ (20  , 5.1 ),
+ (22  , 5.1 ))
egt	  1  2t   value = {1.087e-3*limit(v(2t,3),0,5)*limit((temp-25),-80,125)}
mmain	  2   1   3   3   dmos
rd	  D   4   {rd}    tc = {trd}
dds	  3   4   dds
dbody	  3   D   dbody
ra	  4   2   {ra} 
rs	  3   5   1e-4
ls	  5   S   0.001n 
m1     1t   8   6   6   inter
e1      8   6   4   1t  2
cgd	  7   4   {cgd}   ic = 0
rcgd    7   4   10meg
dgd     6   4   dgd
rdgd    4   6   10meg
m2      7   9  1t  1t   inter
e2      9  1t   4  1t   -2
.ends 
*$
